परफ़ॉर्मेंस को ऑप्टिमाइज़ करना

नियम लिखते समय, परफ़ॉर्मेंस से जुड़ी सबसे आम नुकसान, डिपेंडेंसी से इकट्ठा होने वाले डेटा को ट्रैवर्स या कॉपी करना होता है. पूरे बिल्ड में एग्रीगेट किए जाने पर, इन ऑपरेशन में आसानी से O(N^2) समय या स्पेस लग सकता है. इससे बचने के लिए, डिप्सेट का इस्तेमाल करने का सही तरीका समझना ज़रूरी है.

इसे सही तरीके से लागू करना मुश्किल हो सकता है. इसलिए, Bazel एक मेमोरी प्रोफ़ाइलर भी उपलब्ध कराता है. इससे आपको उन जगहों को ढूंढने में मदद मिलती है जहां आपने गलती की हो सकती है. ध्यान रखें: अगर कोई नियम सही तरीके से नहीं लिखा गया है, तो इसका असर तब तक नहीं दिखेगा, जब तक कि उसका इस्तेमाल बड़े पैमाने पर न किया जाए.

डिपेंडेंसी सेट का इस्तेमाल करना

नियम की डिपेंडेंसी से जानकारी को रोल अप करते समय, आपको depsets का इस्तेमाल करना चाहिए. मौजूदा नियम के हिसाब से स्थानीय जानकारी पब्लिश करने के लिए, सिर्फ़ सामान्य सूचियों या डायक्शनरी का इस्तेमाल करें.

डेपसेट, जानकारी को नेस्ट किए गए ग्राफ़ के तौर पर दिखाता है, जिससे उसे शेयर किया जा सकता है.

नीचे दिया गया ग्राफ़ देखें:

C -> B -> A
D ---^

हर नोड एक स्ट्रिंग पब्लिश करता है. डेपसेट की मदद से, डेटा कुछ ऐसा दिखता है:

a = depset(direct=['a'])
b = depset(direct=['b'], transitive=[a])
c = depset(direct=['c'], transitive=[b])
d = depset(direct=['d'], transitive=[b])

ध्यान दें कि हर आइटम का सिर्फ़ एक बार ज़िक्र किया गया है. सूचियों की मदद से, आपको यह जानकारी मिलेगी:

a = ['a']
b = ['b', 'a']
c = ['c', 'b', 'a']
d = ['d', 'b', 'a']

ध्यान दें कि इस मामले में 'a' का चार बार इस्तेमाल किया गया है! बड़े ग्राफ़ के साथ, यह समस्या और भी बदतर होती जाएगी.

यहां एक नियम लागू करने का एक उदाहरण दिया गया है, जिसमें ट्रांज़िटिव जानकारी को पब्लिश करने के लिए, सही तरीके से डिप्स का इस्तेमाल किया जाता है. ध्यान दें कि अगर आप चाहें, तो सूचियों का इस्तेमाल करके नियम के हिसाब से स्थानीय जानकारी पब्लिश की जा सकती है. ऐसा इसलिए, क्योंकि यह O(N^2) नहीं है.

MyProvider = provider()

def _impl(ctx):
  my_things = ctx.attr.things
  all_things = depset(
      direct=my_things,
      transitive=[dep[MyProvider].all_things for dep in ctx.attr.deps]
  )
  ...
  return [MyProvider(
    my_things=my_things,  # OK, a flat list of rule-local things only
    all_things=all_things,  # OK, a depset containing dependencies
  )]

ज़्यादा जानकारी के लिए, डिपेंडेंसी सेट की खास जानकारी पेज देखें.

depset.to_list() को कॉल करने से बचें

to_list() का इस्तेमाल करके, किसी डिप्सेट को फ़्लैट सूची में रखा जा सकता है. हालांकि, आम तौर पर ऐसा करने से O(N^2) लागत आती है. अगर हो सके, तो डीपसेट को फ़्लैट करने से बचें. ऐसा सिर्फ़ डीबग करने के लिए करें.

एक आम गलतफ़हमी यह है कि अगर सिर्फ़ टॉप-लेवल टारगेट पर डिपेंडेंसी सेट को फ़्लैट किया जाता है, तो <xx>_binary नियम के तौर पर, डिपेंडेंसी सेट को आसानी से फ़्लैट किया जा सकता है. ऐसा इसलिए, क्योंकि तब बिल्ड ग्राफ़ के हर लेवल पर लागत इकट्ठा नहीं की जाती. हालांकि, ओवरलैप होने वाली डिपेंडेंसी वाले टारगेट का सेट बनाने पर, यह अब भी O(N^2) होता है. ऐसा, टेस्ट //foo/tests/... बनाते समय या IDE प्रोजेक्ट इंपोर्ट करते समय होता है.

कॉल की संख्या को depset पर सेट करें

depset को लूप में कॉल करना अक्सर गलती हो जाता है. इससे बहुत गहराई से घोंसला बनाने की समस्या पैदा हो सकती है, जो अच्छी तरह से काम नहीं करती है. उदाहरण के लिए:

x = depset()
for i in inputs:
    # Do not do that.
    x = depset(transitive = [x, i.deps])

इस कोड को आसानी से बदला जा सकता है. सबसे पहले, ट्रांज़िटिव डिप्सेट इकट्ठा करें और उन सभी को एक साथ मर्ज करें:

transitive = []

for i in inputs:
    transitive.append(i.deps)

x = depset(transitive = transitive)

कभी-कभी, सूची के कॉम्प्रेहेंशन का इस्तेमाल करके, इस संख्या को कम किया जा सकता है:

x = depset(transitive = [i.deps for i in inputs])

कमांड लाइन के लिए ctx.actions.args() का इस्तेमाल करना

कमांड लाइन बनाते समय, आपको ctx.actions.args() का इस्तेमाल करना चाहिए. इससे, किसी भी डिप्सेट को एक्सपैंशन करने की प्रोसेस को, प्रोसेस करने के चरण तक के लिए टाल दिया जाता है.

पूरी तरह से तेज़ होने के अलावा, इससे आपके नियमों की मेमोरी खपत कम हो जाएगी -- कभी-कभी 90% या उससे ज़्यादा तक.

यहां कुछ तरकीबें दी गई हैं:

• खुद से डेपसेट और सूचियों को फ़्लैट करने के बजाय, उन्हें सीधे आर्ग्युमेंट के तौर पर पास करें. आपके लिए, इनकी समयसीमा ctx.actions.args() तक बढ़ा दी जाएगी. अगर आपको डेपसेट के कॉन्टेंट में कोई बदलाव करना है, तो ctx.actions.args#add देखें और पता लगाएं कि क्या कोई चीज़ काम की है.

• क्या File#path को आर्ग्युमेंट के तौर पर पास किया जा रहा है? कोई ज़रूरत नहीं है. कोई भी फ़ाइल अपने-आप अपने पाथ में बदल जाती है. यह बदलाव, एक्सपैंशन के समय होता है.

• स्ट्रिंग को एक साथ जोड़कर बनाने से बचें. सबसे अच्छा स्ट्रिंग आर्ग्युमेंट एक कॉन्स्टेंट होता है, क्योंकि इसकी मेमोरी आपके नियम के सभी इंस्टेंस के बीच शेयर की जाएगी.

• अगर कमांड लाइन के लिए आर्ग्युमेंट बहुत लंबे हैं, तो ctx.actions.args#use_param_file का इस्तेमाल करके, ctx.actions.args() ऑब्जेक्ट को शर्त के साथ या बिना शर्त के पैरामीटर फ़ाइल में लिखा जा सकता है. यह कार्रवाई करने के दौरान, पर्दे के पीछे की जाती है. अगर आपको पैरामीटर फ़ाइल को साफ़ तौर पर कंट्रोल करना है, तो ctx.actions.write का इस्तेमाल करके, इसे मैन्युअल तरीके से लिखा जा सकता है.

उदाहरण:

def _impl(ctx):
  ...
  args = ctx.actions.args()
  file = ctx.declare_file(...)
  files = depset(...)

  # Bad, constructs a full string "--foo=<file path>" for each rule instance
  args.add("--foo=" + file.path)

  # Good, shares "--foo" among all rule instances, and defers file.path to later
  # It will however pass ["--foo", <file path>] to the action command line,
  # instead of ["--foo=<file_path>"]
  args.add("--foo", file)

  # Use format if you prefer ["--foo=<file path>"] to ["--foo", <file path>]
  args.add(format="--foo=%s", value=file)

  # Bad, makes a giant string of a whole depset
  args.add(" ".join(["-I%s" % file.short_path for file in files])

  # Good, only stores a reference to the depset
  args.add_all(files, format_each="-I%s", map_each=_to_short_path)

# Function passed to map_each above
def _to_short_path(f):
  return f.short_path

ट्रांज़िटिव ऐक्शन इनपुट, डिप्सेट होने चाहिए

ctx.actions.run का इस्तेमाल करके कोई कार्रवाई बनाते समय, यह मत भूलें कि inputs फ़ील्ड में डेपसेट डाला जा सकता है. जब भी इनपुट, ट्रांज़िशन के ज़रिए डिपेंडेंसी से इकट्ठा किए जाते हैं, तब इसका इस्तेमाल करें.

inputs = depset(...)
ctx.actions.run(
  inputs = inputs,  # Do *not* turn inputs into a list
  ...
)

लटकना

अगर Bazel फ़ंक्शन काम नहीं कर रहा है, तो Ctrl-\ दबाएं या $(bazel info output_base)/server/jvm.out फ़ाइल में थ्रेड डंप पाने के लिए, Bazel को SIGQUIT सिग्नल (kill -3 $(bazel info server_pid)) भेजें.

अगर bazel फ़ंक्शन बंद हो जाता है, तो हो सकता है कि आप bazel info को न चला पाएं. आम तौर पर, output_base डायरेक्ट्री, आपकी वर्कस्पेस डायरेक्ट्री में मौजूद bazel-<workspace> लिंक के पैरंट डायरेक्ट्री होती है.

परफ़ॉर्मेंस प्रोफ़ाइलिंग

JSON ट्रेस प्रोफ़ाइल का इस्तेमाल करके, यह तुरंत समझा जा सकता है कि Bazel ने कॉल के दौरान किस काम पर समय बिताया.

मेमोरी प्रोफ़ाइलिंग

Basel में एक मेमोरी प्रोफ़ाइलर होता है जो आपके नियम में मेमोरी के इस्तेमाल की जांच करने में आपकी मदद कर सकता है. अगर कोई समस्या है, तो उस कोड की सटीक लाइन का पता लगाने के लिए उस हीप को छोड़ें.

मेमोरी ट्रैकिंग की सुविधा चालू करना

आपको Bazel को हर बार इस्तेमाल करने के लिए, ये दो स्टार्टअप फ़्लैग पास करने होंगे:

  STARTUP_FLAGS=\
  --host_jvm_args=-javaagent:<path to java-allocation-instrumenter-3.3.0.jar> \
  --host_jvm_args=-DRULE_MEMORY_TRACKER=1

ये सर्वर को मेमोरी ट्रैकिंग मोड में शुरू करते हैं. अगर एक बार भी बेज़ल इन्वेशन के लिए आप इन्हें भूल जाते हैं, तो सर्वर रीस्टार्ट हो जाएगा और आपको फिर से शुरू करना होगा.

मेमोरी ट्रैकर का इस्तेमाल करना

उदाहरण के लिए, टारगेट foo को देखें और जानें कि यह क्या करता है. सिर्फ़ विश्लेषण चलाने और बिल्ड को लागू करने के फ़ेज़ को न चलाने के लिए, --nobuild फ़्लैग जोड़ें.

$ bazel $(STARTUP_FLAGS) build --nobuild //foo:foo

इसके बाद, देखें कि पूरे Basel इंस्टेंस में कितनी मेमोरी इस्तेमाल होती है:

$ bazel $(STARTUP_FLAGS) info used-heap-size-after-gc
> 2594MB

bazel dump --rules का इस्तेमाल करके, नियम की क्लास के हिसाब से डेटा देखें:

$ bazel $(STARTUP_FLAGS) dump --rules
>

RULE                                 COUNT     ACTIONS          BYTES         EACH
genrule                             33,762      33,801    291,538,824        8,635
config_setting                      25,374           0     24,897,336          981
filegroup                           25,369      25,369     97,496,272        3,843
cc_library                           5,372      73,235    182,214,456       33,919
proto_library                        4,140     110,409    186,776,864       45,115
android_library                      2,621      36,921    218,504,848       83,366
java_library                         2,371      12,459     38,841,000       16,381
_gen_source                            719       2,157      9,195,312       12,789
_check_proto_library_deps              719         668      1,835,288        2,552
... (more output)

bazel dump --skylark_memory का इस्तेमाल करके pprof फ़ाइल बनाकर देखें कि मेमोरी कहां जा रही है:

$ bazel $(STARTUP_FLAGS) dump --skylark_memory=$HOME/prof.gz
> Dumping Starlark heap to: /usr/local/google/home/$USER/prof.gz

ढेर की जांच करने के लिए, pprof टूल का इस्तेमाल करें. pprof -flame $HOME/prof.gz का इस्तेमाल करके फ़्लेम ग्राफ़ बनाना एक अच्छा तरीका है.

pprof को https://github.com/google/pprof से डाउनलोड करें.

सबसे लोकप्रिय कॉल साइटों का एक टेक्स्ट डंप पाएं, जिसके साथ लाइनों की जानकारी दी गई हो:

$ pprof -text -lines $HOME/prof.gz
>
      flat  flat%   sum%        cum   cum%
  146.11MB 19.64% 19.64%   146.11MB 19.64%  android_library <native>:-1
  113.02MB 15.19% 34.83%   113.02MB 15.19%  genrule <native>:-1
   74.11MB  9.96% 44.80%    74.11MB  9.96%  glob <native>:-1
   55.98MB  7.53% 52.32%    55.98MB  7.53%  filegroup <native>:-1
   53.44MB  7.18% 59.51%    53.44MB  7.18%  sh_test <native>:-1
   26.55MB  3.57% 63.07%    26.55MB  3.57%  _generate_foo_files /foo/tc/tc.bzl:491
   26.01MB  3.50% 66.57%    26.01MB  3.50%  _build_foo_impl /foo/build_test.bzl:78
   22.01MB  2.96% 69.53%    22.01MB  2.96%  _build_foo_impl /foo/build_test.bzl:73
   ... (more output)