11.1 完全性制約
個々の完全性制約は、話言葉の散文として、また、可能な場合には、SPARQL[sparql11-query]のASKクエリやクエリ・テンプレートとして表されます。ASKクエリがRDFグラフに適用され、対応する制約に違反する1つ以上のデータ・キューブのインスタンスがそのグラフに含まれていれば、真（true）を返すでしょう。
完全性制約を表すためにSPARQLクエリを用いることは、この方法で完全性チェックを行なわなければならいことを示唆するわけではありません。実装は、同等性チェックを行なうために、別のクエリ式や別の実装技術を自由に使用できます。
個々の完全性制約クエリは、次の接頭辞バインディングを仮定します。
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX qb: <http://purl.org/linked-data/cube#>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
PREFIX owl: <http://www.w3.org/2002/07/owl#>
完全な制約の集合を以下に挙げます。
IC-0. データ型の整合性
RDFグラフは、グラフ内で用いられているすべてのデータ型を含んでいるデータ型マップを用いたRDF D-含意[RDF-MT]の下で整合性がなければなりません。
IC-1. 一意のデータセット
すべてのqb:Observationには、きっかり1つの関連するqb:DataSetがあります。
ASK {
{
# Check observation has a data set
?obs a qb:Observation .
FILTER NOT EXISTS { ?obs qb:dataSet ?dataset1 . }
} UNION {
# Check has just one data set
?obs a qb:Observation ;
qb:dataSet ?dataset1, ?dataset2 .
FILTER (?dataset1 != ?dataset2)
}
}
|
IC-2. 一意のDSD
すべてqb:DataSetには、きっかり1つの関連するqb:DataStructureDefinitionがあります。
ASK {
{
# Check dataset has a dsd
?dataset a qb:DataSet .
FILTER NOT EXISTS { ?dataset qb:structure ?dsd . }
} UNION {
# Check has just one dsd
?dataset a qb:DataSet ;
qb:structure ?dsd1, ?dsd2 .
FILTER (?dsd1 != ?dsd2)
}
}
|
IC-3. DSDが測度を包含
すべてのqb:DataStructureDefinitionには少なくとも1つの宣言された測度が含まれていなければなりません。
ASK {
?dsd a qb:DataStructureDefinition .
FILTER NOT EXISTS { ?dsd qb:component [qb:componentProperty [a qb:MeasureProperty]] }
}
|
IC-4. 次元が値域を持つ
qb:DataStructureDefinitionで宣言されたすべての次元には、宣言されたrdfs:rangeがなければなりません。
ASK {
?dim a qb:DimensionProperty .
FILTER NOT EXISTS { ?dim rdfs:range [] }
}
|
IC-5. 概念次元がコード・リストを持つ
skos:Conceptの値域を有するすべての次元には、qb:codeListがなければなりません。
ASK {
?dim a qb:DimensionProperty ;
rdfs:range skos:Concept .
FILTER NOT EXISTS { ?dim qb:codeList [] }
}
|
IC-6. 属性のみがオプションでありえる
qb:componentRequiredを用いて、オプションと記すことができるqb:DataStructureDefinitionの唯一のコンポーネントは属性です。
ASK {
?dsd qb:component ?componentSpec .
?componentSpec qb:componentRequired "false"^^xsd:boolean ;
qb:componentProperty ?component .
FILTER NOT EXISTS { ?component a qb:AttributeProperty }
}
|
IC-7. スライス・キーが宣言されていなければならない
すべてのqb:SliceKeyはqb:DataStructureDefinitionに関連付けられていなければなりません。
ASK {
?sliceKey a qb:SliceKey .
FILTER NOT EXISTS { [a qb:DataStructureDefinition] qb:sliceKey ?sliceKey }
}
|
IC-8. スライス・キーはDSDと整合性がある
qb:SliceKeyのすべてのqb:componentPropertyも、関連するqb:DataStructureDefinitionのqb:componentとして宣言されなければなりません。
ASK {
?slicekey a qb:SliceKey;
qb:componentProperty ?prop .
?dsd qb:sliceKey ?slicekey .
FILTER NOT EXISTS { ?dsd qb:component [qb:componentProperty ?prop] }
}
|
IC-9. 一意のスライス構造
個々のqb:Sliceには、きっかり1つの関連するqb:sliceStructureがなければなりません。
ASK {
{
# Slice has a key
?slice a qb:Slice .
FILTER NOT EXISTS { ?slice qb:sliceStructure ?key }
} UNION {
# Slice has just one key
?slice a qb:Slice ;
qb:sliceStructure ?key1, ?key2;
FILTER (?key1 != ?key2)
}
}
|
IC-10. スライス次元が完全
すべてのqb:Sliceには、そのqb:sliceStructureで宣言されたすべての次元に対する値がなければなりません。
ASK {
?slice qb:sliceStructure [qb:componentProperty ?dim] .
FILTER NOT EXISTS { ?slice ?dim [] }
}
|
IC-11. すべての次元が必須
すべてのqb:Observationには、その関連するqb:DataStructureDefinitionで宣言された個々の次元に対する値がなければなりません。
ASK {
?obs qb:dataSet/qb:structure/qb:component/qb:componentProperty ?dim .
?dim a qb:DimensionProperty;
FILTER NOT EXISTS { ?obs ?dim [] }
}
|
IC-12. 重複した観測データの禁止
同じqb:DataSet内の2つのqb:Observationは、すべての次元に対して同じ値を持つことができません。
ASK {
FILTER( ?allEqual )
{
# For each pair of observations test if all the dimension values are the same
SELECT (MIN(?equal) AS ?allEqual) WHERE {
?obs1 qb:dataSet ?dataset .
?obs2 qb:dataSet ?dataset .
FILTER (?obs1 != ?obs2)
?dataset qb:structure/qb:component/qb:componentProperty ?dim .
?dim a qb:DimensionProperty .
?obs1 ?dim ?value1 .
?obs2 ?dim ?value2 .
BIND( ?value1 = ?value2 AS ?equal)
} GROUP BY ?obs1 ?obs2
}
}
|
IC-13. 必須の属性
すべてのqb:Observationには、必須と記されている個々の宣言された属性に対する値があります。
ASK {
?obs qb:dataSet/qb:structure/qb:component ?component .
?component qb:componentRequired "true"^^xsd:boolean ;
qb:componentProperty ?attr .
FILTER NOT EXISTS { ?obs ?attr [] }
}
|
IC-14. すべての測度が存在する
測度次元を用いないqb:DataSetにおいては、個々のqb:Observationに、すべての宣言された測度に対して値がなければなりません。
ASK {
# Observation in a non-measureType cube
?obs qb:dataSet/qb:structure ?dsd .
FILTER NOT EXISTS { ?dsd qb:component/qb:componentProperty qb:measureType }
# verify every measure is present
?dsd qb:component/qb:componentProperty ?measure .
?measure a qb:MeasureProperty;
FILTER NOT EXISTS { ?obs ?measure [] }
}
|
IC-15. 測度次元に整合性がある
測度次元を用いるqb:DataSetにおいては、個々のqb:Observationに、その与えられたqb:measureTypeに対応する測度に対して値がなければなりません。
ASK {
# Observation in a measureType-cube
?obs qb:dataSet/qb:structure ?dsd ;
qb:measureType ?measure .
?dsd qb:component/qb:componentProperty qb:measureType .
# Must have value for its measureType
FILTER NOT EXISTS { ?obs ?measure [] }
}
|
IC-16. 測度次元観測データに1つの測度
測度次元を用いるqb:DataSetにおいては、個々のqb:Observationには、1つの測度に対する値のみがなければなりません（IC-15によって、これはそのqb:measureTypeに対応する測度になるでしょう）。
ASK {
# Observation with measureType
?obs qb:dataSet/qb:structure ?dsd ;
qb:measureType ?measure ;
?omeasure [] .
# Any measure on the observation
?dsd qb:component/qb:componentProperty qb:measureType ;
qb:component/qb:componentProperty ?omeasure .
?omeasure a qb:MeasureProperty .
# Must be the same as the measureType
FILTER (?omeasure != ?measure)
}
|
IC-17. 測度次元キューブにすべての測度が存在する
測度次元を用いるqb:DataSetにおいては、非測度次元のある組み合わせに対する観測データがあれば、個々の宣言された測度に対する同じ非測度次元の値を有する他の観測データがなければなりません。
ASK {
{
# Count number of other measures found at each point
SELECT ?numMeasures (COUNT(?obs2) AS ?count) WHERE {
{
# Find the DSDs and check how many measures they have
SELECT ?dsd (COUNT(?m) AS ?numMeasures) WHERE {
?dsd qb:component/qb:componentProperty ?m.
?m a qb:MeasureProperty .
} GROUP BY ?dsd
}
# Observation in measureType cube
?obs1 qb:dataSet/qb:structure ?dsd;
qb:dataSet ?dataset ;
qb:measureType ?m1 .
# Other observation at same dimension value
?obs2 qb:dataSet ?dataset ;
qb:measureType ?m2 .
FILTER NOT EXISTS {
?dsd qb:component/qb:componentProperty ?dim .
FILTER (?dim != qb:measureType)
?dim a qb:DimensionProperty .
?obs1 ?dim ?v1 .
?obs2 ?dim ?v2.
FILTER (?v1 != ?v2)
}
} GROUP BY ?obs1 ?numMeasures
HAVING (?count != ?numMeasures)
}
}
|
IC-18. 整合性があるデータセット・リンク
qb:DataSet Dにqb:slice Sがあり、Sにqb:observation Oがあれば、Oに対応するqb:dataSetはDでなければなりません。
ASK {
?dataset qb:slice ?slice .
?slice qb:observation ?obs .
FILTER NOT EXISTS { ?obs qb:dataSet ?dataset . }
}
|
IC-19. コード・リストからのコード
次元プロパティーにqb:codeListがあれば、すべてのqb:Observationの次元プロパティーの値がコード・リストになければなりません。
次の完全性チェック・クエリは、チェックするデータ・キューブと、コード・リストの定義を含んでいるRDFグラフに適用されなければなりません。skos:ConceptSchemeの場合には、個々の概念はskos:inSchemeを用いてスキームにリンクされなければなりません。skos:Collectionの場合には、集合はskos:memberを用いて、個々の概念（または、入れ子の集合に）にリンクしなければなりません。集合がskos:memberListを用いれば、[SKOS-REFERENCE]のS36によって定義されているskos:memberの値の含意は、このチェックが適用される前に、実現されなければなりません。
ASK {
?obs qb:dataSet/qb:structure/qb:component/qb:componentProperty ?dim .
?dim a qb:DimensionProperty ;
qb:codeList ?list .
?list a skos:ConceptScheme .
?obs ?dim ?v .
FILTER NOT EXISTS { ?v a skos:Concept ; skos:inScheme ?list }
}
ASK {
?obs qb:dataSet/qb:structure/qb:component/qb:componentProperty ?dim .
?dim a qb:DimensionProperty ;
qb:codeList ?list .
?list a skos:Collection .
?obs ?dim ?v .
FILTER NOT EXISTS { ?v a skos:Concept . ?list skos:member+ ?v }
}
|
IC-20. 階層からのコード
次元プロパティーに非空白qb:parentChildPropertyを有するqb:HierarchicalCodeListがある場合、すべてのqb:Observationのその次元プロパティーの値は、qb:parentChildPropertyリンクに沿った0以上のホップ（hop）を用いて、階層のルートから到達できなければなりません。
このチェックは、シンプルな固定SPARQLクエリで行うことができません。その代わりに、クエリ・テンプレートが提供されています。テンプレートのインスタンスは、そのqb:parentChildPropertyに対してIRIの値を持っている個々のqb:HierarchicalCodeListに対して生成されるべきです。それは、次のインスタンス化クエリ内の?pの個々のバインディングに関するものです。
SELECT ?p WHERE {
?hierarchy a qb:HierarchicalCodeList ;
qb:parentChildProperty ?p .
FILTER ( isIRI(?p) )
}
その後、テンプレートは、文字列$pを、インスタンス化クエリによって見つかったIRIと置換することによりインスタンス化されます。テンプレートは次のとおりです。
ASK {
?obs qb:dataSet/qb:structure/qb:component/qb:componentProperty ?dim .
?dim a qb:DimensionProperty ;
qb:codeList ?list .
?list a qb:HierarchicalCodeList .
?obs ?dim ?v .
FILTER NOT EXISTS { ?list qb:hierarchyRoot/<$p>* ?v }
}
|
IC-21. 階層からのコード（逆）
次元プロパティーに逆のqb:parentChildPropertyを有するqb:HierarchicalCodeListがある場合、すべてのqb:Observationのその次元プロパティーの値は、逆のqb:parentChildPropertyリンクに沿った0以上のホップを用いて、階層のルートから到達できなければなりません。
このチェックは、シンプルな固定SPARQLクエリで行うことができません。その代わりに、クエリ・テンプレートが提供されています。テンプレートのインスタンスは、関連する逆のプロパティーで、そのqb:parentChildPropertyに対して空白ノードの値を持っている個々のqb:HierarchicalCodeListに対して生成されるべきです。それは、次のインスタンス化クエリの?pの個々のバインディングに関するものです。
SELECT ?p WHERE {
?hierarchy a qb:HierarchicalCodeList;
qb:parentChildProperty ?pcp .
FILTER( isBlank(?pcp) )
?pcp owl:inverseOf ?p .
FILTER( isIRI(?p) )
}
その後、テンプレートは、文字列$pを、インスタンス化クエリによって見つかったIRIと置換することによりインスタンス化されます。テンプレートは次のとおりです。
ASK {
?obs qb:dataSet/qb:structure/qb:component/qb:componentProperty ?dim .
?dim a qb:DimensionProperty ;
qb:codeList ?list .
?list a qb:HierarchicalCodeList .
?obs ?dim ?v .
FILTER NOT EXISTS { ?list qb:hierarchyRoot/(^<$p>)* ?v }
}
|
